代码收藏家技术教程 2023-01-10

使用ESP8266连接阿里云，通过MQTT上传温湿度信息

1、注册阿里云设备信息

1）在阿里云中选择物联网平台并添加相应的产品信息

每个场景都有自己对应的属性信息，根据自己项目进行选择，这里我选择室内温湿度监测设备。添加完产品后，需要对产品进行功能的定义，

直接点击产品名称，就可以进入设置界面，

点击编辑草稿进行相应功能的配置，

这里由于我选择的是标准化的产品所以可以选择添加标准功能，这里要注意对应功能的标识符，后续代码中要按照此标识符进行数据传输，否则无法正确解析数据。至此已经完成了产品的添加。

2）添加相应的设备信息

在设备中选择添加设备，并进行相应的设备信息设置。首先选择前面注册的产品，然后再为新建的设备取一个名称（后面用得上）。完成设备的添加后就可以查看自己添加的设备信息了。点击查看，便可以看到连接MQTT连接所需要的三元组其中DeviceName为刚才我们自行设置设备的名称（注意不是产品名称），至此我们已经完成了阿里云上设备的添加。（注意此时的设别还是处理未激活的状态，需要我们使用esp8266连接成功后，才会显示在线状态）

2、esp8266开发

1）在Arduino中添加esp8266开发环境的配置

https://www.arduino.cn/package_esp8266com_index.json将此网址添加至Arduino首选项中添加开发环境

2）在Arduino中添加MQTT相应的库文件

由于本实验采用的是DHT11温湿度传感器，所以添加的相应的库文件。在工具中，选择管理库进行在线添加库文件。

在搜索框中，输入头文件对应的名称，添加对应的头文件。

并将Arduino库中的PubSubClient.h头文件进行修改。

在Arduino中选择esp8266开发环境，并确定设备端口。

使用MQTT.fx接入物联网平台 – 阿里云物联网平台 – 阿里云（网页计算工具）

代码中对应的设备标识符。

完整的代码如下：

#include <ESP8266WiFi.h>
/* 依赖 PubSubClient 2.4.0 */
#include <PubSubClient.h>
/* 依赖 ArduinoJson 5.13.4 */
#include <ArduinoJson.h>

#include <DFRobot_DHT11.h>
DFRobot_DHT11 DHT;
#define DHT11_PIN 2                 //pin2  对应的是D4引脚

/* 连接您的WIFI SSID和密码 */
#define WIFI_SSID         "本地WIFI名称"    
#define WIFI_PASSWD       "wifi密码"        

/* 设备的三元组信息*/
#define PRODUCT_KEY       "gxh6JBk483w"                       //阿里云中对应的设备的PRODUCT_KEY
#define DEVICE_NAME       "Device_01"                         //修改为自己阿里云中设备的DEVICE_NAME
#define DEVICE_SECRET     "5a93b1aa589bc981478a88a735e514c6"  //DEVICE_SECRET
#define REGION_ID         "cn-shanghai"                       //注册阿里云服务器对应的地区

/* 线上环境域名和端口号，不需要改 */
#define MQTT_SERVER       PRODUCT_KEY ".iot-as-mqtt." REGION_ID ".aliyuncs.com"
#define MQTT_PORT         1883
#define MQTT_USRNAME      DEVICE_NAME "&" PRODUCT_KEY

#define CLIENT_ID         "ESP8266|securemode=2,signmethod=hmacsha1,timestamp=1646788871139|"

#define MQTT_PASSWD       "B262D51FA7CC7AE05ED185CE6B5FD6EBD80F64BE"   //使用阿里云平台中的密码解析网址进行破解，https://help.aliyun.com/document_detail/86706.html

#define ALINK_BODY_FORMAT         "{\"id\":\"ESP8266\",\"version\":\"1.0\",\"method\":\"thing.event.property.post\",\"params\":%s}"
#define ALINK_TOPIC_PROP_POST     "/sys/" PRODUCT_KEY "/" DEVICE_NAME "/thing/event/property/post"


unsigned long lastMs = 0;
float RH,T,RH_sum,T_sum;
unsigned char count=0;
WiFiClient espClient;
PubSubClient  client(espClient);
//SHTC3 mySHTC3;

void callback(char *topic, byte *payload, unsigned int length)
{
    Serial.print("Message arrived [");
    Serial.print(topic);
    Serial.print("] ");
    payload[length] = '\0';
    Serial.println((char *)payload);

}

void wifiInit()
{
    WiFi.mode(WIFI_STA);
    WiFi.begin(WIFI_SSID, WIFI_PASSWD);   //连接WiFi
    while (WiFi.status() != WL_CONNECTED)
    {
        delay(1000);
        Serial.println("WiFi not Connect");
    }
    Serial.println("Connected to AP");
    Serial.println("IP address: ");
    Serial.println(WiFi.localIP());    
    Serial.print("espClient [");
    client.setServer(MQTT_SERVER, MQTT_PORT);   /* 连接WiFi之后，连接MQTT服务器 */
    client.setCallback(callback);
}

void mqttCheckConnect()
{
    while (!client.connected())
    {
        Serial.println("Connecting to MQTT Server ...");
        if (client.connect(CLIENT_ID, MQTT_USRNAME, MQTT_PASSWD))

        {
            Serial.println("MQTT Connected!");
        }
        else
        {
            Serial.print("MQTT Connect err:");
            Serial.println(client.state());
            delay(5000);
        }
    }
}

void mqttIntervalPost()
{
    char param[32];
    char jsonBuf[128];
    sprintf(param, "{\"CurrentTemperature\":%f}",T_sum/count);
    sprintf(jsonBuf, ALINK_BODY_FORMAT, param);
    Serial.println(jsonBuf);
    boolean d = client.publish(ALINK_TOPIC_PROP_POST, jsonBuf);
    if(d){
      Serial.println("publish Temperature success"); 
    }else{
      Serial.println("publish Temperature fail"); 
    }
    
    sprintf(param, "{\"CurrentHumidity\":%f}",RH_sum/count);
    sprintf(jsonBuf, ALINK_BODY_FORMAT, param);
    Serial.println(jsonBuf);
    d = client.publish(ALINK_TOPIC_PROP_POST, jsonBuf);
    if(d){
      Serial.println("publish Humidity success"); 
    }else{
      Serial.println("publish Humidity fail"); 
    }
}

void setup() 
{

    Serial.begin(115200);
    Serial.println("Demo Start");
    wifiInit();
    unsigned char i=0;

}

// the loop function runs over and over again forever
void loop()
{
  DHT.read(DHT11_PIN);
  delay(1000);                  //延时1000毫秒

    RH = DHT.humidity;   //读取湿度数据                       
    T = DHT.temperature;       //读取温度数据
    RH_sum+=RH;
    T_sum+=T;
    count+=1;                    

  Serial.print("Humidity:");  //向串口打印 Humidity:
  Serial.print(RH);           //向串口打印湿度数据
  Serial.print("%");
  Serial.print("  Temperature:");
  Serial.print(T);            //向串口打印温度数据
  Serial.println("C"); 

  mqttCheckConnect();     //上线平台连接

  if (millis() - lastMs >= 30000)   //30000（ms）
  {
    lastMs = millis();

    /* 上报 */
    mqttIntervalPost();
    count=0;
    RH_sum=0;
    T_sum=0;
  }
  client.loop();
}

至此已经完成了对esp8266的配置，此时设备应该可以正常上线。

3、阿里云中查看设备上传信息

登录阿里云物联网平台点击设备，再点击查看便可以看点相关的设备信息，再点击物模型数据，就可以查看到从esp8266中上传的数据。